Finances personnelles et argent
2017-08-10 19:35:20 +0000
18

Comment calculer les intérêts composés mensuels dans Google Sheets ?

Je dispose d'un tableur financier avec une colonne de tous mes dépôts sur mon compte d'épargne. La colonne de gauche indique les dates des dépôts. Supposons que mon solde d'épargne soit de 100,00 $ et que mon intérêt mensuel soit de 0,25 % (1/4 de 1 %). Il s'agit de l'intérêt composé payé le dernier jour de chaque mois. Autrement dit, à la fin d'un mois, je reçois 100,00*0,0025 (soit 100,02). À la fin du mois suivant, je reçois 100,02 *0,0025. Et ainsi de suite. Existe-t-il une formule financière qui me permette de calculer cela dans Google Sheets ? Je préférerais que tout soit dans une seule cellule en disant quelque chose comme "Intérêts : $-.--" Merci.

Réponses [2]

21
2017-08-10 20:27:02 +0000

Il suffit d'utiliser la formule des intérêts composés :

Principle * (1 + Rate / Time) ^ Time

enter image description here

Pour la cellule C2, vous voulez cette formule :

=B2*(((1+(D$1/360))^(C$1-$A2))-1)
  • La colonne A est la date de dépôt
  • La colonne B est le montant du dépôt
  • La cellule C1 est la date du jour
  • La cellule D1 est le taux d'intérêt annuel

La plupart des comptes d'épargne que je connais ont des intérêts composés quotidiens et des intérêts créditeurs mensuels, donc en réalité la formule ci-dessus sera exacte à la date du jour, même si une partie des intérêts ne vous a pas encore été créditée.

Vous pouvez également ignorer la formule d'intérêt composé actuelle et utiliser simplement la formule de valeur future intégrée :

=FV(D$1/360,C$1-$A2,0,-B2)-B2

Pour approfondir la question des intérêts composés mensuels, vous devez commencer à jouer avec l'ajustement des dates...

Vous pouvez commencer par prendre les deux dates et calculer le nombre de mois écoulés en utilisant la fonction DATEDIF() comme ceci :

=DATEDIF(A2,C$1,"M")

Mais vous devrez ajuster les deux dates car un simple DATEDIFF entre la date d'aujourd'hui et les cellules A3 et A4 retournera 2, ce qui n'est pas vraiment correct. Vous pourriez prendre le premier jour du mois suivant du dépôt en utilisant

=EOMONTH(A2,0)+1

Et vous pouvez prendre le premier jour du mois du mois en cours avec

=DATE(YEAR(C1),MONTH(C1),1)

Ce qui fait votre formule :

=B2*(((1+(D$1/12))^(DATEDIF(EOMONTH($A2,0)+1,DATE(YEAR(C$1),MONTH(C$1),1),"M")))-1)

Mais ce n'est pas vraiment correct car les intérêts ne commencent à s'accumuler que le premier du mois suivant le dépôt. Vous pouvez aussi obtenir un nombre approximatif de mois en soustrayant les deux dates et en divisant par 30 jours.

Vous pouvez rendre plus compliqué le calcul du nombre de jours pour le premier mois + les intérêts mensuels complets au-delà, mais cela rend la formule beaucoup plus longue parce que vous aurez

First month in days interest + monthly interest beyond that

Pour obtenir le nombre de jours restants dans un mois, vous feriez quelque chose du genre :

=EOMONTH($A2,0) - $A2

Donc pour obtenir la proportion du reste du mois que vous avez (jours survenus dans le mois divisés par le nombre de jours dans le mois) :

=(EOMONTH($A2,0) - $A2) / DAY(EOMONTH($A2,0))

Puis multipliez ce qui précède par le taux d'intérêt mensuel multiplié par le principe pour obtenir le mois partiel, puis ajoutez les intérêts mensuels ci-dessus.

=($B2*(((EOMONTH($A2,0)-$A2)/DAY(EOMONTH($A2,0))*($D$1/12))))+(B2*(((1+(D$1/12))^(DATEDIF(EOMONTH($A2,0)+1,DATE(YEAR(C$1),MONTH(C$1),1),"M")))-1))

Mais n'oubliez pas que le montant du principal sur les intérêts mensuels est maintenant votre principal + les intérêts qui ont été crédités le premier mois, donc votre formule devrait être la bonne :

=($B2*(((EOMONTH($A2,0)-$A2)/DAY(EOMONTH($A2,0))*($D$1/12))))+(($B2*1+((((EOMONTH($A2,0)-$A2)/DAY(EOMONTH($A2,0))*($D$1/12)))))*(((1+(D$1/12))^(DATEDIF(EOMONTH($A2,0)+1,DATE(YEAR(C$1),MONTH(C$1),1),"M")))-1))

À ce stade, vous coupez vraiment les cheveux en quatre car c'est la différence entre 1,74327 $ d'intérêts et 1,74331 $ lorsque l'on inclut les intérêts du premier mois dans le capital pour les mois restants. Cela diffère des 1,85 $ de la cellule C2 ci-dessus parce que vous n'avez pas encore été crédité pour les 10 premiers jours du mois d'août. Dans de nombreux cas, les minuscules différences de composition n'ont d'importance que pour les gros montants, et même alors.... Si vous aviez 10 000 000 $ en principe, la différence de composition passerait de 0,00004 $ à 4 $. Dans la plupart des cas, la première formule de calcul est plus que suffisante (et probablement celle que j'utiliserais dans tous les cas, car la différence pratique de composition quotidienne par rapport à la composition mensuelle n'est pas significative).

21
11
2018-07-01 02:32:58 +0000

C'est ce que fait la fonction "Valeur future".

=FV(rate, number_of_periods, payment_amount, present_value, [end_or_beginning])

Par exemple :

=FV(2%, 12, -100, -400, 0)

Notez que le montant du paiement et la valeur actuelle doivent tous deux être saisis sous forme de nombres négatifs, sinon il en résulte une valeur négative

Voir l'article support Google pour plus d'informations et les fonctions connexes.

11

Questions connexes